« 関連付けファイルのショートカットの引数がドロップで消えないようにする。 | トップページ | HTMLファイルにドロップで引数を渡す。 »

2007年2月14日 (水)

CSVファイルを表形式で表示する。

Start CsvView.HTA CSVファイル

<HTML><HEAD><hta:application id="hta"></hta:application>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html;CHARSET=x-sjis">
<TITLE>CsvView.HTA</TITLE>
<OBJECT ID="TDC" WIDTH=0 HEIGHT=0 CLASSID="CLSID:333C7BC4-460F-11D0-BC04-0080C7055A83">
<PARAM NAME="UseHeader" VALUE="true">
<PARAM NAME="Charset" VALUE="shift_jis">
<PARAM NAME="CaseSensitive" VALUE="false">
</OBJECT><SCRIPT LANGUAGE="VBScript">
Option Explicit
Dim arg
Dim fQuoting
Dim k
fQuoting=False
arg=hta.commandline
For k=1 To Len(arg)
  Select Case Mid(arg,k,1)
  Case Chr(34) fQuoting=Not fQuoting
  Case Chr(32) If Not fQuoting Then Exit For
  End Select
Next
arg=Mid(arg,k+1)
arg=Trim(Replace(arg,Chr(34),Empty))
If arg="" Then
  alert "CSV file name missing."
  close
Else
  TDC.DataURL=arg
End If

Sub window_onload()
Dim RS
Dim HTML
Dim Field
document.title=document.title & " - " & TDC.DataURL
Set RS=TDC.recordset
HTML="<" & "TABLE DATASRC=""#TDC"" BORDER><" & "THEAD><" & "TR>"
For Each Field In RS.Fields
  HTML=HTML & "<" & "TD>" & Field.Name & "<" & "/TD>"
Next
HTML=HTML & "<" & "/TR><" & "/THEAD><" & "TBODY><" & "TR>"
For Each Field In RS.Fields
  HTML=HTML & "<" & "TD><" & "SPAN DATAFLD=""" & Field.Name & """><" & "/SPAN><" & "/TD>"
Next
HTML=HTML & "<" & "/TR><" & "/TBODY><" & "/TABLE>"
document.body.innerHTML=HTML
End Sub
</SCRIPT></HEAD><BODY ></BODY></HTML>

これを、SendToフォルダに入れておくか、CSVファイルに関連付けておくとよいでしょう。

MSHTA.EXE "フルパス\CsvView.HTA" "%1"

« 関連付けファイルのショートカットの引数がドロップで消えないようにする。 | トップページ | HTMLファイルにドロップで引数を渡す。 »