« エクスプローラから起動されたバッチファイルでPAUSEする。(その2) | トップページ | 「Web ページ、完全」で保存すると、ファイル名が変更できない。 »

2007年12月19日 (水)

Cookieを削除する。

Cookie削除の警告ダイアログを出さずに、Cookieだけを削除する方法はどうもなさそうです。:-(
Cookiesフォルダ側の実体だけを消しても、Cacheフォルダ側の情報が消えないし。

なので、WSFで、Cookie削除の警告ダイアログに自動応答します。

以下は、キャッシュファイルとCookieの両方を削除します。

<package>
<job id=main>
<script language=vbscript>
Option Explicit
Dim wShell
Dim oExec
Set wShell=CreateObject("WScript.Shell")
Set oExec=wShell.Exec("WScript.exe //job:sub """ & WScript.ScriptFullName & """")
Do While oExec.Status=0
  If wShell.AppActivate("警告") Then wShell.SendKeys "%y"
  WScript.Sleep 1000
Loop
</script>
</job>
<job id=sub>
<script language=vbscript>
CreateObject("Shell.Application").NameSpace(32).Items().InvokeVerbEx("delete")
</script>
</job>
</package>

以下は、Cookieだけを削除します。

<package>
<job id=main>
<script language=vbscript>
Option Explicit
Dim wShell
Dim oExec
Set wShell=CreateObject("WScript.Shell")
Set oExec=wShell.Exec("WScript.exe //job:sub """ & WScript.ScriptFullName & """")
Do While oExec.Status=0
  If wShell.AppActivate("警告") Then wShell.SendKeys "%y"
  WScript.Sleep 100
Loop
</script>
</job>
<job id=sub>
<script language=vbscript>
Option Explicit
Dim Folder
Dim FolderItem
Set Folder=CreateObject("Shell.Application").NameSpace(32)
For Each FolderItem In Folder.Items()
  If Left(Folder.GetDetailsOf(FolderItem,1),7)="Cookie:" Then FolderItem.InvokeVerb("delete")
Next
</script>
</job>
</package>

« エクスプローラから起動されたバッチファイルでPAUSEする。(その2) | トップページ | 「Web ページ、完全」で保存すると、ファイル名が変更できない。 »